*Tutorial 2

*Learning Mata by example


**looping in Mata

*--------------Start Example  1 ----------------*

mata
a=(1,2,3,4,5,6,7,8,9,10)
a

for (i=1;i<=10;i++) {
a[i]        //loops through a, one element of vector at a time
}

end

*--------------End Example------------------*
help m2_for



*looping through rows and columns

*--------------Start Example  2 ----------------*

mata
a=(1,2,3,4,5,6,7,8,9,10\11,12,13,14,15,16,17,18,19,100 )
a


for (i1=1;i1<=cols(a);i1++) {       //column loop, the max number is columns of a  eg. cols(a)
for (i=1;i<=rows(a);i++) {          //row loop, the max number is rows of a  eg. rows(a)
a[i,i1]        //loops through a, one element of vector at a time. Starting with first column
}
}
end

*--------------End Example------------------*
help m2_for


*--------------Start Example  3 ----------------*

sysuse auto, clear
set more off

mata
a=st_data(.,(2,3))
a

for (i1=1;i1<=cols(a);i1++) {       //column loop, the max number is columns of a  eg. cols(a)
for (i=1;i<=rows(a);i++) {          //row loop, the max number is rows of a  eg. rows(a)
a[i,i1]        //loops through a, one element of vector at a time. Starting with first column
}
}
end

*--------------End Example------------------*
help mf_st_data



*printing output rather than list matrix
*--------------Start Example  4 ----------------*

sysuse auto, clear
set more off

mata
a=st_data(.,(2,3))
a

for (i=1;i<=rows(a);i++) {          //row loop, the max number is rows of a  eg. rows(a)
printf("              %13.2f", a[i,1]) 
printf("       %13.2f\n ", a[i, 2]) 
}

end

*--------------End Example------------------*
help mf_st_data


*looping through strings

*--------------Start Example  5 ----------------*

sysuse auto, clear
set more off

mata
a=st_sdata(.,1)
a

for (i=1;i<=rows(a);i++) {
printf("this is a make of car:    %s\n", a[i])     //mata command for printing to results window
}
end

*--------------End Example------------------*
help mf_st_data


//***************************************************************
*if statement
//***************************************************************



*--------------Start Example  6 ----------------*

mata
a=(1,2,3,4,5,6,7,8,9,10)
a

for (i=1;i<=cols(a);i++) {

if (a[i]<5) {
a[i]        //loops through a, one element of vector at a time
}
}
end

*--------------End Example------------------*
help m2_if


* Before putting  mod() in an if statement, first see what mod() does

*--------------Start Example  7 ----------------*

mata

a=(1,2,3,4,5,6,7,8,9,10)
a
for (i=1;i<=cols(a);i++) {

b=mod(a[i],2)
b
}
end

*--------------End Example------------------*
help mf_mod




*list every 2nd element

*--------------Start Example  8 ----------------*


mata
a=(1,2,3,4,5,6,7,8,9,10)
a

for (i=1;i<=cols(a);i++) {

if (mod(i,2)==0) {
a[i]        //loops through a, one element of vector at a time
}
}
end

*--------------End Example------------------*



*populate every a matrix with every 2nd element
*--------------Start Example  9 ----------------*


mata
a=(1,2,3,4,5,6,7,8,9,10)
a

b=J(cols(a),1,.)
b

for (i=1;i<=cols(a);i++) {

if (mod(i,2)==0) {
b[i]=a[i]                   //loops through a, one element of vector at a time
}
}
b
end

*--------------End Example------------------*




*populate every a matrix with every 2nd element but with no missing values
*--------------Start Example  10 ----------------*


mata
a=(1,2,3,4,5,6,7,8,9,10)
a

b=J(cols(a)/2,1,.)             //note divide by 2
b

z=1                            //z is our new indexing scalar
for (i=1;i<=cols(a);i++) {

if (mod(i,2)==0) {
b[z]=a[i]        //loops through a, one element of vector at a time
z=z+1
}
}
b
end

*--------------End Example------------------*


**exercise
**add up all the elements of a if they are less than 15

*--------------Start Example  11 ----------------*


mata
a=(1,2,13,41,5,6,17,8,19,110)
a

b=0
for (i=1;i<=cols(a);i++) {

if (a[i]<15) {
b=b+a[i]        //loops through a, one element of vector at a time
}
}
b
end

*--------------End Example------------------*



**exercise
**find the minimum in a

*--------------Start Example  12 ----------------*


mata
a=(11,12,13,41,5,6,17,8,19,110)
a

b=a[1]
for (i=1;i<=cols(a);i++) {

if (a[i]<b) {
b=a[i]     
}
}
b
end

*--------------End Example------------------*





**note this can be done with a mata function
** type: help m5_intro
** scrolling down the rowmin() function looks good

*--------------Start Example  13 ----------------*

mata
a=(11,12,13,41,5,6,17,8,19,110)
a

b=rowmin(a)     

b
end

*--------------End Example------------------*
help mf_minmax


*create a matrix with a converted into a 2 x 5 matrix, ie 2 row and 5 columns (r,c)
**once again looking at the mata functions this time for floor() and ceil()

*--------------Start Example  14 ----------------*

mata
a=(11,12,13,41,5,6,17,8,19,110)
a

b=J(5,2,.)
b

for (i=1;i<=cols(a);i++) {

a[i]
if (mod(i,2)==1) {
b[floor(i/2)+1,1]=a[i]
}

else {
b[ceil(i/2),2]=a[i]
}


}
b
end

*--------------End Example------------------*



*create a matrix with a is made into a 2 x 5 matrix, ie 2 row and 5 columns (r,c)
*another way  of doing this
*--------------Start Example  15 ----------------*


mata
a=(11,12,13,41,5,6,17,8,19,110)
a


z=0
for (i=1;i<=cols(a)-1;i++) {

if (mod(i,2)==1 )

if ( z==0 ) {
b=(a[i],a[i+1])

z=1
}
else {
b=(b\(a[i],a[i+1]))

}

}
b
end

*--------------End Example------------------*


*create a matrix with a is made into a 2 x 5 matrix, ie 2 row and 5 columns (r,c)
*another way  of doing this. Easy if you use colshape(). It paids to look if a function exists
*--------------Start Example  16 ----------------*


mata
a=(11,12,13,41,5,6,17,8,19,110)
a

b=colshape(a,2)

b
end

*--------------End Example------------------*




//produce a matrix, based on another matrix but with 0 eliminated
*--------------Start Example  17 ----------------*

mata

a=(0\2\3\0\5\6\7)
a
z=1
for (i=1;i<=rows(a);i++) {


if (a[i]!=0){


if (z==1) {
b=a[i]
z=2
b
}
else {
b=(b\a[i])
}



}  //end if (a[i]!=0)
}  //end loop

b

end
*--------------End Example------------------*



//or the above can be done with select()
*--------------Start Example  18 ----------------*
mata
A = (1,2,3,4,0,5,6,0,0,7)
A2 = select(A, A:>0)
A2
end

*--------------End Example------------------*



*End Tutorial 2